Функциональные блоки на языке ST

[kondor3000]

Вот, чего я добивался, выкладываю. На вход Enable установил RS, пририсовал независимые входы Val1-4 для независимой установки времени шагов и паузы между ними, выкинул фнкцию funMul, а необходимое значение шагов записал на прямую.

Это всё хорошо, только зачем было разбираться с Т триггером и в итоге поставить RS триггер? И главное он даже не отключает блок на 9 шаге)))

Пример из Oscat, можно перерисовать прямо со скрина, это тоже Т триггер, только без использования R-триггера, если это интересно)
А вообще любую открытую биб-ку ( и Oscat), можно открыть как проект и скопировать код.
Только не всегда всё просто, этот пример в Лоджике будет с ошибкой, хоть и не сложной.

А разложение Маски на биты, на ST ещё проще b0:=Mask.0; b1:=Mask.1; b2:=Mask.2; b3:=Mask.3; ....... b7:=Mask.7;

[Urfin_Dzhyus]

Это всё хорошо, только зачем было разбираться с Т триггером и в итоге поставить RS триггер?

На работе RS встал сразу и полностью меня удавлетварил, даже более чем, а ТТ для интереса и как вариант исполнения и задницеподгорания). У меня реально дома проблема с лоджиком, а если бы я тупил, я бы сам об этом сказал не стесьняясь, ведь то количество выкуренного и выпитого позволяет к таким вещам относится философически)))
ЗЫ: Разобрался с лоджиком, оказывается я подключал тестируемые триггеры к глючному блоку с форума)))

[Urfin_Dzhyus]

Это всё хорошо, только зачем было разбираться с Т триггером и в итоге поставить RS триггер? И главное он даже не отключает блок на 9 шаге)))

Пример из Oscat, можно перерисовать прямо со скрина, это тоже Т триггер, только без использования R-триггера, если это интересно)
А вообще любую открытую биб-ку ( и Oscat), можно открыть как проект и скопировать код.
Только не всегда всё просто, этот пример в Лоджике будет с ошибкой, хоть и не сложной.

А разложение Маски на биты, на ST ещё проще b0:=Mask.0; b1:=Mask.1; b2:=Mask.2; b3:=Mask.3; ....... b7:=Mask.7;

Гляжу вы также как и я по полдня ответы пишете и по нескольку раз редактируете.

Пример из Oscat, можно перерисовать прямо со скрина, это тоже Т триггер, только без использования R-триггера, если это интересно)

Перевёл, он что и должен постоянно генерить при единице на клике?

А разложение Маски на биты, на ST ещё проще b0:=Mask.0; b1:=Mask.1; b2:=Mask.2; b3:=Mask.3; ....... b7:=Mask.7;

Я думал над блоком GetMasc, но не вижу особого смысла менять один кусок кода на другой. В этом плане я полный оппортунист, мне что кубики, что крякозябры, всё это просто код облечённый в разные обёртки.

[kondor3000]

Перевёл, он что и должен постоянно генерить при единице на клике?

Генерить он не должен.
Это точно такой же Т- триггер, как ранее обсуждали и работать должен так же, если у вас не так, значит не правильно перевели.
Даже по коду видно, что если нет сброса, есть сигнал на входе и нет в промежуточной переменной, то инвертировать выход Q:= not Q;

[БАЙТ]

Здравствуйте .Обращаюсь к представителю Овен.Есть ли возможность посмотреть код st функционального блока PID регулятора ?Или посмотрите этот код Снимок экрана (6).png.

[FPavel]

БАЙТ, я не представитель Овен.

В CoDeSys библиотека Util позволяет ознакомиться с PID регулятором на ST

PID из Util:

(* PD controller *)
FUNCTION_BLOCK PID
VAR_INPUT
	ACTUAL :REAL;		(* actual value, process variable *)
	SET_POINT:REAL;	(* desired value, set point *)
	KP:REAL;				(* proportionality const. (P)*)
	TN:REAL;				(* reset time (I) in sec *)
	TV:REAL;				(* rate time, derivative time (D) in sec*)
	Y_MANUAL:REAL;		(* Y is set to this value as long as MANUAL=TRUE *)
	Y_OFFSET:REAL;		(* offset for manipulated variable *)
	Y_MIN:REAL;			(* minimum value for manipulated variable *)
	Y_MAX:REAL;			(* maximum value for manipulated variable *)
	MANUAL:BOOL;		(* 	TRUE: manual: Y is not influenced by controller,
								FALSE: controller determines Y *)
	RESET:BOOL;			(* reset: set Y output to Y_OFFSET and reset integral part *)
END_VAR
VAR_OUTPUT
	Y:REAL;				(* manipulated variable, set value*)
	LIMITS_ACTIVE:BOOL:=FALSE;	(* true set value would exceed limits Y_MIN, Y_MAX *)
	OVERFLOW:BOOL:=FALSE;		(* overflow in integral part *)
END_VAR
VAR
	CLOCK:TON;
	I: INTEGRAL;
	D: DERIVATIVE;
	TMDIFF: DWORD;
	ERROR: REAL;
	INIT: BOOL:=TRUE;
	Y_ADDOFFSET: REAL;
	KPcopy:REAL;
	TNcopy:REAL;
	TVcopy:REAL;
END_VAR

IF TN>0 AND KP<> 0 AND (NOT OVERFLOW OR RESET OR MANUAL) THEN
	ERROR := SET_POINT-ACTUAL;								(* Regeldifferenz *)

	IF RESET OR MANUAL OR INIT OR (KP<>KPcopy OR TN<>TNcopy OR TV<>TVcopy) THEN							(* Reset oder Handbetrieb *)
		I(RESET:=TRUE);
		D(RESET:=TRUE);
		OVERFLOW:=FALSE;
		LIMITS_ACTIVE:=FALSE;
		IF RESET OR INIT THEN
			Y := Y_OFFSET;
			INIT:=FALSE;
			Y_ADDOFFSET := 0;
		ELSIF MANUAL THEN
			Y := Y_MANUAL;
			Y_ADDOFFSET := Y_MANUAL-(Y_OFFSET+KP*(ERROR+I.OUT/TN+D.OUT*TV));
		ELSE
			Y_ADDOFFSET := Y - Y_OFFSET - KP*ERROR;
		END_IF
		TMDIFF:=0;
		CLOCK(IN:=FALSE);									(* Timer neu starten *)
		CLOCK(PT:=t#1h, IN:=TRUE);

		TNcopy := TN;
		TVcopy := TV;
		KPcopy := KP;
	ELSE
		CLOCK;												(* Timer abfragen *)
		TMDIFF:=TIME_TO_DWORD(CLOCK.ET);					(* Zeitdifferenz seit letztem Aufruf *)
	END_IF;

	IF TMDIFF>0 THEN
		CLOCK(IN:=FALSE);									(* Timer neu starten *)
		CLOCK(PT:=t#1h, IN:=TRUE);

		D(IN:=ERROR, TM:=TMDIFF, RESET:=FALSE);				(* Differential absch&#228;tzen *)
		I(IN:=ERROR, TM:=TMDIFF, RESET:=FALSE);				(* Integral absch&#228;tzen *)

		OVERFLOW := I.OVERFLOW;
		IF NOT OVERFLOW THEN
			Y:=Y_OFFSET+KP*(ERROR+I.OUT/TN+D.OUT*TV) + Y_ADDOFFSET;
			IF Y>1E30 OR Y<-1E30 THEN						(* Overflow steht bevor, darf aber eigentlich nicht passieren *)
				OVERFLOW:=TRUE;
			END_IF;

			LIMITS_ACTIVE:=FALSE;
			IF Y_MAX>Y_MIN AND Y>Y_MAX  THEN				(* Stellwert-Obergrenze &#252;berschritten *)
				LIMITS_ACTIVE:=TRUE;
				IF KP<>0 THEN
					I(IN:=(Y_MAX-Y)*TN/KP,TM:=1000,RESET:=FALSE);		(* Integral korrigieren *)
				END_IF
				Y:=Y_MAX;
			END_IF;
			IF Y_MAX>Y_MIN AND Y<Y_MIN THEN					(* Stellwert-Untergrenze unterschritten *)
				LIMITS_ACTIVE:=TRUE;
				IF KP<>0 THEN
					I(IN:=(Y_MIN-Y)*TN/KP,TM:=1000,RESET:=FALSE);		(* Integral korrigieren *)
				END_IF
				Y:=Y_MIN;
			END_IF;
		END_IF;
	ELSE
		CLOCK(PT:=t#1h,IN:=TRUE);
	END_IF;

END_IF;

Ещё открыт исходник ПИД регулятора из компонентов OwenLogic, хоть и на FBD.

[БАЙТ]

За код спасибо!А тот код не мой, нейросеть пример привела.

[ПавелП]

За код спасибо!А тот код не мой, нейросеть пример привела.

Похоже что скоро ИИ нам сможет толковые советы давать.

Вот, обещались.

[Ruslanadm]

Народ, а как макрос SelChgF в виде FB на ST написать?
Может, кто поделится мыслями, а то что-то самому не представить...

[1exan]

function_block SelChgF //имя функционального блока.

    var_input //объявление входных переменных
       var1_F : real;
       var2_F : real;
    end_var

    var_output 
       out : real; 
    end_var

    var 
       var1_F_mem : real;
       var2_F_mem : real;
    end_var

    if var1_F_mem <> var1_F then
        out := var1_F;
    elsif var2_F_mem <> var2_F then
        out := var2_F;
    end_if
    
    var1_F_mem := var1_F;
    var2_F_mem := var2_F; 

end_function_block